#include "colors.inc"
#include "shapes.inc"
#include "shapes2.inc"
#include "textures.inc"
#include "chars.inc"
#include "stones1.inc"

#declare Cover_Texture = pigment {
	color Brown
}

#declare Frame_Texture = texture {
	DMFDarkOak
	pigment {
		quick_color Brown
	}
}

#declare Green_Metal_Texture = texture {
	pigment {
		color Green
	}
	finish {
		Metal
	}
}

#declare Desk_leg = box {
	<0, 0, 0>, <0.3, -4, 0.3>
}

#declare Desk = union {
	box {
		<0, -0.2, 0>, <7, 0, 4>
	}

	object {
		Desk_leg
		translate <0.5, -0.2, 0.5>
	}

	object {
		Desk_leg
		translate <6.5, -0.2, 0.5>
	}

	object {
		Desk_leg
		translate <0.5, -0.2, 3.5>
	}

	object {
		Desk_leg
		translate <6.5, -0.2, 3.5>
	}
}

#declare PLATONIA = union {
	object {
		char_P
		translate <0, 0, 0>
	}

	object {
		char_L
		translate <4, 0, 0>
	}

	object {
		char_A
		translate <8, 0, 0>
	}

	object {
		char_T
		translate <12, 0, 0>
	}

	object {
		char_O
		translate <16, 0, 0>
	}

	object {
		char_N
		translate <20, 0, 0>
	}

	object {
		char_I
		translate <24, 0, 0>
	}

	object {
		char_A
		translate <28, 0, 0>
	}
}

#declare Platonia_Label = union {
	box {
		<0, 0, 0>, <0.8, -0.4, -0.01>
		pigment {
			color White
		}
	}

	object {
		PLATONIA
		scale <0.8/32.0, 0.4/5, 0.02>
		translate <0, -0.4, -0.03>
		texture {
			pigment {
				color Green 
			}
		}
	}
}

#declare Book = union {
	box {
		<0, 0, 0>, <1, 1.41, 0.05>
		texture {
			Cover_Texture
		}
	}

	box {
		<0, 0.1, 0.05>, <0.9, 1.27, 0.3>
		pigment {
			color White
		}
	}

	box {
		<0, 0, 0.3>, <1, 1.41, 0.35>
		texture {
			Cover_Texture
		}
	}

	box {
		<-0.01, 0, 0>, <0.05, 1.41, 0.35>
		texture {
			Cover_Texture
		}
	}

	object {
		Platonia_Label
		translate <0.1, 1.31, 0>
	}

	translate <-0.5, -0.705, 0.175>		// so that the origin 
						// is in the middle
}

#declare Column = union {
	cylinder {
		<0, 0, 0>, <0, 0.3, 0>, 1.2
		texture {
			PinkAlabaster
		}
	}

	cone {
		<0, 0.3, 0>, 0.8, <0, 3.5, 0>, 0.6
		texture {
			Blood_Marble
		}
	}

	cylinder {
		<0, 3.5, 0>, <0, 3.6, 0>, 1.2
		texture {
			PinkAlabaster
		}
	}

	scale <0.5, 1, 0.5>
}

#declare myCanvas = union {
	// Canvas
	box {
		<-0.1,-0.1, 0>, <0.9, 0.9, -0.01>
		pigment {
			color White
//			quick_color Green
		}
		finish {
			ambient 1.0
			diffuse 1.0
		}
	}

	triangle {
		<0.230, 0.333, -0.02>, <0.563, 0.333, -0.02>, 
			<0.443, 0.493, -0.02>
		texture {
			Mirror
			pigment {
				color White
				quick_color Red
			}
		}
	}

	triangle {
//		<0.230, 0.333, -0.02>, <0, 0.640, -0.02>, 
//			<0.214, 0.800, -0.02>
		<0.230, 0.333, -0.02>, <0.070, 0.546, -0.02>,
			<0.283, 0.706, -0.02>
		texture {Copper_Texture}
	}

	triangle {
//		<0.214, 0.800, -0.02>, <0.443, 0.493, -0.02>, 
//			<0.230, 0.333, -0.02>
		<0.283, 0.706, -0.02>, <0.443, 0.493, -0.02>,
			<0.230, 0.333, -0.02>
		texture {Copper_Texture}
	}

	triangle {
		<0.443, 0.493, -0.02>, <0.603, 0.613, -0.02>, 
			<0.723, 0.453, -0.02>
		texture {Green_Metal_Texture}
	}

	triangle {
		<0.723, 0.453, -0.02>, <0.563, 0.333, -0.02>,
			<0.443, 0.493, -0.02>
		texture {Green_Metal_Texture}
	}

	box {
		<0.230, 0, -0.02>, <0.563, 0.333, -0.02>
		texture {Gold_Texture}
	}

	translate <0.1, -0.9, 0>
}

#declare Picture = union {
	// Nail
	cylinder {
		<0, 0, 0>, <0, 0, -0.01>, 0.02
		texture {
			Silver_Texture
			pigment {
				quick_color Green
			}
		}
	}

	// Holder
	cylinder {
		<0, 0, 0>, <-0.3, -0.2, 0>, 0.01
		pigment {
			color Brown
		}
	}
	cylinder {
		<0, 0, 0>, <0.3, -0.2, 0>, 0.01
		pigment {
			color Brown
		}
	}

	// Frame
	box {
		<-0.55,-0.2,0>, <0.55,-0.3,-0.05>
		texture {
			Frame_Texture
		}
	}
	box {
		<-0.55,-1.3,0>, <0.55, -1.4, -0.05>
		texture {
			Frame_Texture
		}
	}
	box {
		<-0.55, -0.2, 0>, <-0.50, -1.4, -0.05>
		texture {
			Frame_Texture 
		}
	}
	box {
		<0.50, -0.2, 0>, <0.55, -1.4, -0.05>
		texture {
			Frame_Texture
		}
	}

// Canvas
	object {
		myCanvas
		translate <-0.50, -0.3, 0>
	}

}
	
///////////////////////////////////////////////////////////////////////////////

camera {
	location	<5, 1,  0.57>
	look_at		<0, 0,  3>
//	direction	<0, 0,  0.33>
}

light_source {
	<2, 4, -3>	color White
}

light_source {
	<0, 4, 1>	color White
}

object {
	Desk
	texture {
		DMFWood4
	}
	translate	<-3.5, 0, 1>
}

object {
	Book
	scale .6
	rotate <90, -90, 0>
	translate <3.2, 0.35+0.175, 1.3>
}

object {
	Tetrahedron
	texture {
		Jade
	}
	scale 0.15
	translate <3,0,3.5>
}
	
//object {
//	Cube
//	texture {
//		Copper_Texture
//		pigment {
//			quick_color Blue
//		}
//	}
//
//	scale 0.025
//	rotate <45, 45, 45>
//	translate <3.90,0.63-0.025,1.05>
//}

object {
	Cube
	texture {
		Copper_Texture
		pigment {
			quick_color Blue
		}
	}

	scale .22
	translate <2.0, 0.22, 3.5>
}

object {
	Octahedron
	texture {
		Sapphire_Agate
	}

	scale 0.15
	translate <3.2, 0.25, 2.3>
}

object {
	Column
	scale <1, 0.5, 1>
	translate <-2.5, 0, 2>
}

object {
	Dodecahedron
	texture {
		Bright_Blue_Sky
	}
	scale 0.5
	translate <-2.5, 2.3, 2>
}

object {
	Column 
	scale <1, 0.5, 1>
	translate <-2.5, 0, 4>
}

object {
	Icosahedron

	texture {
		T_Stone21
	}

	scale 0.5
	translate <-2.5, 2.45, 4>
}

sphere {
	<0, 0.5, 3>, 0.5

//	texture {
//		tiles {
//			texture { 
//				Stone18
//				pigment {
//					quick_color Green
//				}
//			}
//		tile2
//			texture {
//				Stone21
//				pigment {
//					quick_color Red
//				}
//			}
//		}
//		scale 0.333	
//	}

	texture {
		Glass
	}


	finish {
		ior 3.0
		refraction 1
		reflection 0.2
		brilliance 8.0
	}		
}
		
plane {
	<0, 1, 0>,	-4
	texture {
		tiles {
			texture {
				DMFLightOak
			}
		tile2
			texture {
				DMFDarkOak
			}
		}
	}
}

plane {
	<0, 1, 0>,	10
	texture {
		DMFWood3
	}
}

plane {
	<0, 0, 1>,	10
	texture {
		DMFWood3
	}
}

plane {
	<1, 0, 0>,	-6
	texture {
		DMFWood3
	}
}

object {
	Picture
	scale 2
	translate <-3, 3, 10>
}